Blog · Inventor · 1 Oct 2026 · Last updated 13 Oct 2026 · 6 min read · By Stefano B.

Inventor base view orientation for STEP parts at any angle

A part from a STEP file can sit at any angle, and none of Inventor's standard views then shows its true shape. Measured on a test plate in Inventor 2025, the three-view test for parts on the axes, an iLogic rule that points the view camera at the largest flat face, and the mirror trap when you straighten the body instead.

Short answer: for a plate that lies along the model axes, make the Front, Top and Right base views and keep the largest. For a part that sits at an angle, none of the three shows the true shape: take the largest flat face, point the base view camera along its normal, with its longest straight edge across the sheet, then add the projected views. Measured on a 200 × 120 × 12 mm test plate in Inventor 2025.

Test plate 200 x 120 x 12 mm from a tilted STEP file: the largest of the Front, Top and Right base views is a slanted view 207.2 x 153.3 mm, with the holes drawn as ellipses.
From this: the largest of the three standard views of a tilted plate is 207.2 × 153.3 mm, not the plate.
The same tilted STEP plate after the camera rule: base view 200 x 120 mm at true size, with two projected views 12 mm thick, one to the right and one below.
To this: the same STEP file after the camera rule below, 200 × 120 at true size, projected views 12 mm thick.

Our answer in the Autodesk forum thread Create drawing for each part places one base view per part. Which view to place is this page, and it matters on every fabrication drawing from a STEP file. The step before is splitting a multi-body STEP into part files.

The test part

Our own plate, drawn in Inventor and exported to STEP: 200 × 120 × 12 mm, a 30 × 30 corner chamfer, holes Ø22 and Ø14, and a 45° × 6 mm bevel on one face of the short left edge. Two STEP files: one lying on the XY plane, one turned 35° about X and then 25° about Y, the way bodies often arrive in a STEP file.

Top does not look at XY

Test plate lying on the XY plane in three base views: Front 200 x 120 looks along Z, Top 200 x 12 looks along Y, Right 12 x 120 looks along X.
The plate lies on XY. Front shows the face; Top shows the edge.

On the plate lying on XY (thickness along Z), Inventor 2025 gives: Front 200 × 120, Top 200 × 12, Right 12 × 120. From the sizes: kFrontViewOrientation looks along Z, kTopViewOrientation along Y and kRightViewOrientation along X. Mapping "Top = XY" draws the plate on its edge.

Method 1: three trial views, keep the largest

Run it in the part (the STEP file opened in Inventor). It opens a new drawing with one base view.

' Base view: try Front, Top and Right, keep the largest.
Dim oPart As PartDocument = ThisDoc.Document
Dim oTG As TransientGeometry = ThisApplication.TransientGeometry
Dim trialScale As Double = 1.0
Dim oDrw As DrawingDocument = ThisApplication.Documents.Add(DocumentTypeEnum.kDrawingDocumentObject, _
    ThisApplication.FileManager.GetTemplateFile(DocumentTypeEnum.kDrawingDocumentObject))
Dim oSheet As Sheet = oDrw.ActiveSheet
Dim oris() As ViewOrientationTypeEnum = {ViewOrientationTypeEnum.kFrontViewOrientation, _
    ViewOrientationTypeEnum.kTopViewOrientation, ViewOrientationTypeEnum.kRightViewOrientation}
Dim oBest As DrawingView = Nothing
Dim bestArea As Double = 0
For Each ori As ViewOrientationTypeEnum In oris
    Dim vtmp As DrawingView = oSheet.DrawingViews.AddBaseView(oPart, _
        oTG.CreatePoint2d(oSheet.Width / 2, oSheet.Height / 2), trialScale, _
        ori, DrawingViewStyleEnum.kHiddenLineRemovedDrawingViewStyle)
    Dim area As Double = vtmp.Width * vtmp.Height
    If area > bestArea Then
        If oBest IsNot Nothing Then oBest.Delete()
        oBest = vtmp
        bestArea = area
    Else
        vtmp.Delete()
    End If
Next

What to change:

On the plate lying on XY it keeps Front, 200 × 120. On the tilted plate it keeps Top, 207.2 × 153.3: the largest of three wrong views (first image above). No error, no warning.

Method 2: point the camera at the largest flat face

' Base view looking straight at the largest flat face, for a part at any angle.
' Run it in the part (the STEP file opened in Inventor).
Dim oPart As PartDocument = ThisDoc.Document
Dim oTG As TransientGeometry = ThisApplication.TransientGeometry
Dim viewScale As Double = 1.0   ' scale of the views
Dim gap As Double = 3.0         ' cm between the views on the sheet

' 1. largest flat face of the first body
Dim oBody As SurfaceBody = oPart.ComponentDefinition.SurfaceBodies.Item(1)
Dim oFace As Face = Nothing
Dim bestArea As Double = 0
For Each f As Face In oBody.Faces
    If f.SurfaceType = SurfaceTypeEnum.kPlaneSurface Then
        If f.Evaluator.Area > bestArea Then
            oFace = f
            bestArea = f.Evaluator.Area
        End If
    End If
Next

' 2. its normal, pointing out of the material
Dim oPlane As Plane = oFace.Geometry
Dim n As Vector = oPlane.Normal.AsVector()
If oFace.IsParamReversed Then n.ScaleBy(-1)

' 3. its longest straight edge goes across the sheet
Dim u As Vector = Nothing
Dim bestLen As Double = 0
For Each e As Edge In oFace.Edges
    If e.CurveType = CurveTypeEnum.kLineSegmentCurve Or e.CurveType = CurveTypeEnum.kLineCurve Then
        Dim d As Vector = e.StartVertex.Point.VectorTo(e.StopVertex.Point)
        If d.Length > bestLen Then
            u = d
            bestLen = d.Length
        End If
    End If
Next
Dim up As Vector = n.CrossProduct(u)

' 4. base view, then turn its camera
Dim oDrw As DrawingDocument = ThisApplication.Documents.Add(DocumentTypeEnum.kDrawingDocumentObject, _
    ThisApplication.FileManager.GetTemplateFile(DocumentTypeEnum.kDrawingDocumentObject))
Dim oSheet As Sheet = oDrw.ActiveSheet
Dim pos As Point2d = oTG.CreatePoint2d(oSheet.Width * 0.35, oSheet.Height * 0.6)
Dim oBase As DrawingView = oSheet.DrawingViews.AddBaseView(oPart, pos, viewScale, _
    ViewOrientationTypeEnum.kFrontViewOrientation, DrawingViewStyleEnum.kHiddenLineRemovedDrawingViewStyle)
Dim oCam As Camera = oBase.Camera
Dim t As Point = oCam.Target
oCam.Eye = oTG.CreatePoint(t.X + n.X * 100, t.Y + n.Y * 100, t.Z + n.Z * 100)
oCam.UpVector = up.AsUnitVector()
oCam.ApplyWithoutTransition()

' 5. projected views follow the turned base view
Dim oRight As DrawingView = oSheet.DrawingViews.AddProjectedView(oBase, _
    oTG.CreatePoint2d(pos.X + oBase.Width / 2 + gap, pos.Y), DrawingViewStyleEnum.kFromBaseDrawingViewStyle)
Dim oBelow As DrawingView = oSheet.DrawingViews.AddProjectedView(oBase, _
    oTG.CreatePoint2d(pos.X, pos.Y - oBase.Height / 2 - gap), DrawingViewStyleEnum.kFromBaseDrawingViewStyle)

What to change:

Measured on the tilted plate: base view 200 × 120, projected views 12 × 120 and 200 × 12. We also placed the projected views first and turned the camera after: they updated to the same sizes.

On our tilted STEP, IsParamReversed was True for the largest face: Plane.Normal pointed into the material. The flip in step 2 points it out, so the camera looks at the face from outside.

On our plate the largest flat face is the back one (230.159 cm²): the bevel takes a 6 mm strip off the other face. So the view shows the plate from the back: the corner chamfer is bottom right instead of top right, and the bevel appears in the view below. If you need a given side up, choose the face yourself.

If you straighten the body instead: the mirror trap

When you need a part file with the face on a model plane, the other way is to straighten the body: copy it with TransientBRep.Copy, transform the copy with a matrix whose rows are u, n and u × n, and save it as a new part. Then kTopViewOrientation shows the face. On the tilted plate: top view 200 × 120.

Left: the test plate, corner chamfer top right. Right: the copy straightened with a determinant -1 matrix, corner chamfer bottom right. Same volume 274.031 cm3, same box, same 200 x 120 view.
Same sizes. Corner chamfer top right on the part, bottom right on the copy: a mirrored part.

Flip only the normal (rows u, −n, u × n) and the determinant becomes −1. Inventor transforms the body without a warning: same volume (274.031 cm³), same box (200 × 12 × 120 mm), same 200 × 120 top view. But it is the mirror image of the part: in the same view the corner chamfer is bottom right instead of top right. Read Matrix.Determinant before the transform: it must be +1. To turn the part over, flip u and n together: the determinant stays +1.

Do and don't

Do

Don't

Questions people ask

Does code that runs without errors mean the views are right? No. The tilted plate gets a 207.2 × 153.3 view from Method 1, and the mirrored copy passes the volume, box and view-size checks. Look at the drawing.

Does turning the camera break the projected views? Not in our test: projected views placed before or after the camera change measured 12 × 120 and 200 × 12.

Next step: overall and hole dimensions on the view.

If you would rather have the drawings than the code: steel fabrication drawings from your STEP file.

References