Blog · Inventor · 1 Oct 2026 · Last updated 14 Oct 2026 · 6 min read · By Stefano B.

Inventor auto balloon: the rules that work, and when to place balloons by hand

Two ways to balloon a big assembly drawing in Inventor. Automatic, after a person has placed the views and sections - the rules that took a 144-body sheet to 1 arrow crossing. And by hand, with two iLogic rules that write the part names and check that no part is missing.

Short answer: Inventor's Auto Balloon is not in the API, so the placement is up to your code. Two ways work for us:

Measured on this drawing

By hand4 h

With StepToCut30 min

-87%time saved

Screen recording of the run in Autodesk Inventor. Times from the job: balloons and parts list by hand from scratch, against the automatic run with our check.

Before: a sheet with 6 views and 3 sections placed by hand, no balloons.
Before: a sheet with 6 views and 3 sections placed by hand, no balloons.
After one run: 144 balloons in orange, 1 arrow crossing.
After one run: 144 balloons in orange, 1 arrow crossing.

Part A: automatic balloons, the rules

The views and the sections are placed by a person first. Where to cut a section is a judgment on the part, not a formula. The code starts from the sheet as it is.

Then the code decides, for every part:

  1. Which view. It measures how much of the part each view shows: on a copy of the sheet, every view is switched to hidden lines and the visible and hidden length of the part's edges is added up. The part goes in the view where it shows most.
  2. A section wins whenever the part shows in it (5% or more): sections are made to show parts.
  3. An isometric view only when the part does not show in any other view.
  4. No view gets more than 1.5 times the average number of balloons.
  5. Where. A map of the free space on the sheet, made from the lines that are drawn. First a spot inside the view, within 35 mm of the arrow tip, trying the directions always in the same order, starting top-right. Same parts get the same offset, so the balloons line up in rows. If there is no room, a lane just outside the view (balloon centres about 9 mm from the view frame), in the same order as the arrow tips, so the arrows of one side do not cross. Never on another view or the title block.
  6. What it writes. Only the number, without the job prefix: the balloon stays 10.7 mm wide instead of 17.9 mm, and fewer of them touch.
  7. The parts list goes in the largest free area, with the largest text that fits: 3.2 mm here.
Zoom on the top view: each balloon next to its part, in rows.
Zoom on the top view: each balloon next to its part, in rows.

Measured on the same sheet, against the version a designer ballooned by hand:

By hand Automatic
Balloons 177 144 (one per solid body)
Inside the view frame 113 86
Arrow crossings 0 1
Arrow length, median / longest 23 / 88 mm 13 / 69 mm
Balloon pairs that touch 5 1
Arrow tip more than 5 mm off the edge not measured 4

Identical bodies share a number, so the same number can appear twice on the sheet. The designer still adds one thing the code does not: 39 parts get a second balloon in a second view, on purpose.

The measuring part

This is the loop that measures how much of each part a view shows (excerpt from the rule we ran; vis = visible length, nas = hidden length, per part):

For Each c As DrawingCurve In v.DrawingCurves
    Dim nome As String = Nothing
    Try
        Dim gm As Object = c.ModelGeometry
        If TypeOf gm Is Inventor.Edge Then
            nome = CType(gm, Inventor.Edge).Parent.Name
        ElseIf TypeOf gm Is Inventor.Face Then
            nome = CType(gm, Inventor.Face).Parent.Name
        Else
            Continue For
        End If
    Catch
        Continue For
    End Try
    If Not vis.ContainsKey(nome) Then vis(nome) = 0 : nas(nome) = 0
    For Each s As DrawingCurveSegment In c.Segments
        Dim L As Double = Lunghezza(s)
        If s.HiddenLine Then nas(nome) += L Else vis(nome) += L
    Next
Next

Two things we paid for:

Why not a simpler rule

We started from the one-click rule of Jelte de Jong (hjalte.nl/106): one balloon per part, on the side of the view closest to the part. It is the starting point of our placement. On our 115-part test panel, with a single view, each simple rule fails in its own way:

Our first rule on the 115-part panel: 196 balloon pairs touch.
Our first rule on the 115-part panel: 196 balloon pairs touch.
Jelte de Jong's rule on the same panel: 178 arrow crossings.
Jelte de Jong's rule on the same panel: 178 arrow crossings.

And one trap that is still in every rule that attaches to the middle of an edge: if that middle is hidden behind another part, the arrow lands on the wrong part.

The middle of the longest edge is hidden: the arrow lands on another part.
The middle of the longest edge is hidden: the arrow lands on another part.

Part B: big assemblies, place them by hand

Balloons placed by hand come out perfect: the person who knows the job puts each one where it is easy to find, in the view that is best for the welder. On a big assembly that is often still the best solution, and the code above does not beat it.

So we keep the placement by hand and automate the two things a person should not do by hand on a sheet like this: write the right number in every balloon, and check that none is missing.

Rule 1: write the part name in every balloon

On a multi-body part, every balloon placed by hand shows 1: for Inventor the whole model is one BOM item. On an assembly it shows the BOM item number, not your part name. The rule follows each arrow to the part it touches and writes that part's name with OverrideValue (Value stays the BOM item).

' Number the balloons you placed by hand.
' Each balloon gets the name of the part its arrow touches:
'   multi-body part -> the solid body name ("P-012.2" is written as "P-012")
'   assembly        -> the Part Number of the component
' A balloon whose arrow touches nothing gets "X", so you can find it on the sheet.
Dim doc As DrawingDocument = ThisDoc.Document
Dim sheet As Sheet = doc.ActiveSheet
Dim done As Integer = 0
Dim inTheAir As Integer = 0

For Each bal As Balloon In sheet.Balloons
    Dim name As String = ""
    Try
        Dim lastNode As LeaderNode = bal.Leader.AllNodes.Item(bal.Leader.AllNodes.Count)
        Dim intent As GeometryIntent = lastNode.AttachedEntity
        Dim curve As DrawingCurve = intent.Geometry
        Dim geom As Object = curve.ModelGeometry
        If TypeOf geom Is EdgeProxy Then
            Dim occ As ComponentOccurrence = CType(geom, EdgeProxy).ContainingOccurrence
            name = occ.Definition.Document.PropertySets.Item("Design Tracking Properties").Item("Part Number").Value
        Else
            name = geom.Parent.Name
            Dim dot As Integer = name.LastIndexOf(".")
            If dot > 0 AndAlso IsNumeric(name.Substring(dot + 1)) Then name = name.Substring(0, dot)
        End If
    Catch
        name = ""
    End Try

    If name = "" Then
        bal.BalloonValueSets.Item(1).OverrideValue = "X"
        inTheAir += 1
    Else
        bal.BalloonValueSets.Item(1).OverrideValue = name
        done += 1
    End If
Next

Logger.Info("Balloons numbered: " & done & "   arrow touching nothing (X): " & inTheAir)

What to change: the "Part Number" property, if your shop reads another one (for example "Description"). The report goes to the iLogic Log.

Tested: on the 177-balloon sheet placed by hand (multi-body) it wrote the same name as our delivery script on 177 balloons out of 177. On our 115-part panel (assembly) it numbered 97 balloons with the Part Number. The "X" branch is not tested: Inventor did not let us create a balloon with a free arrow through the API.

Rule 2: check that no part is missing

' Check that every part has a balloon. Run it after the numbering rule.
' Lists the parts with no balloon, the balloons marked "X" and the parts ballooned more than once.
Dim doc As DrawingDocument = ThisDoc.Document
Dim sheet As Sheet = doc.ActiveSheet
Dim model As Document = sheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument

' 1. the parts of the model
Dim parts As New List(Of String)
If model.DocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
    For Each occ As ComponentOccurrence In CType(model, AssemblyDocument).ComponentDefinition.Occurrences
        If Not occ.Visible Then Continue For
        Dim pn As String = occ.Definition.Document.PropertySets.Item("Design Tracking Properties").Item("Part Number").Value
        If Not parts.Contains(pn) Then parts.Add(pn)
    Next
Else
    For Each body As SurfaceBody In CType(model, PartDocument).ComponentDefinition.SurfaceBodies
        If Not body.Visible Then Continue For
        Dim nm As String = body.Name
        Dim dot As Integer = nm.LastIndexOf(".")
        If dot > 0 AndAlso IsNumeric(nm.Substring(dot + 1)) Then nm = nm.Substring(0, dot)
        If Not parts.Contains(nm) Then parts.Add(nm)
    Next
End If

' 2. what the balloons say
Dim count As New Dictionary(Of String, Integer)
Dim inTheAir As Integer = 0
For Each bal As Balloon In sheet.Balloons
    Dim txt As String = bal.BalloonValueSets.Item(1).OverrideValue
    If txt = "" Then txt = bal.BalloonValueSets.Item(1).Value
    If txt = "X" Then inTheAir += 1 : Continue For
    If count.ContainsKey(txt) Then count(txt) += 1 Else count(txt) = 1
Next

' 3. the report
Dim missing = parts.Where(Function(x) Not count.ContainsKey(x)).ToList()
Dim twice = count.Where(Function(kv) kv.Value > 1).Select(Function(kv) kv.Key & " x" & kv.Value).ToList()
Logger.Info("Parts: " & parts.Count & "   balloons: " & sheet.Balloons.Count & "   X: " & inTheAir)
Logger.Info("Missing (" & missing.Count & "): " & String.Join(", ", missing))
Logger.Info("More than once (" & twice.Count & "): " & String.Join(", ", twice))

What to change: DrawingViews.Item(1) is the view whose model is checked; hidden parts and bodies are left out on purpose.

What it found, on files we already had:

How long it takes on a real job: assembly drawing with balloons, 4 hours down to 30 minutes.

Related: if your parts come as one multi-body STEP, split it into part files first. To run these rules without opening the iLogic editor, see running an iLogic rule from outside Inventor.